configure_file(${CMAKE_CURRENT_SOURCE_DIR}/scripts/maketarball.sh.in ${CMAKE_CURRENT_SOURCE_DIR}/scripts/maketarball.sh @ONLY)
if(RPM_DISTRO AND RPM_DATE)
  configure_file(${CMAKE_CURRENT_SOURCE_DIR}/unix/strawberry.spec.in ${CMAKE_BINARY_DIR}/strawberry.spec @ONLY)
endif()

if(APPLE)
  if(DEFINED ENV{MACOSX_DEPLOYMENT_TARGET})
    set(LSMinimumSystemVersion $ENV{MACOSX_DEPLOYMENT_TARGET})
  else()
    set(LSMinimumSystemVersion 12.0)
  endif()

  if(BUILD_FOR_MAC_APP_STORE)
    # MAS builds must not embed Sparkle update configuration in Info.plist.
    configure_file(${CMAKE_CURRENT_SOURCE_DIR}/macos/Info.mas.plist.in ${CMAKE_CURRENT_BINARY_DIR}/macos/Info.plist)
  else()
    # Sparkle (macOS updates)
    # These values are embedded into Info.plist and control where the app checks for updates.
    # Downstream builders can override on the CMake command line:
    #   -DSPARKLE_FEED_URL="https://example.com/appcast.xml"
    #   -DSPARKLE_PUBLIC_ED25519_KEY="base64=="
    #
    # Defaults preserve upstream behavior, but are intentionally configurable for third-party builds.
    if(NOT DEFINED SPARKLE_FEED_URL)
      set(SPARKLE_FEED_URL "https://www.strawberrymusicplayer.org/sparkle-macos-@ARCH@")
    endif()
    if(NOT DEFINED SPARKLE_PUBLIC_ED25519_KEY)
      set(SPARKLE_PUBLIC_ED25519_KEY "/OydhYVfypuO2Mf7G6DUqVZWW9G19eFV74qaDCBTOUk=")
    endif()

    configure_file(${CMAKE_CURRENT_SOURCE_DIR}/macos/Info.plist.in ${CMAKE_CURRENT_BINARY_DIR}/macos/Info.plist)
  endif()
endif()

if(WIN32)
  configure_file(${CMAKE_CURRENT_SOURCE_DIR}/windows/windres.rc.in ${CMAKE_BINARY_DIR}/windres.rc)
  configure_file(${CMAKE_CURRENT_SOURCE_DIR}/windows/strawberry.nsi.in ${CMAKE_BINARY_DIR}/strawberry.nsi @ONLY)
endif()

if(UNIX AND NOT APPLE)
  install(FILES ../data/icons/48x48/strawberry.png DESTINATION share/icons/hicolor/48x48/apps/)
  install(FILES ../data/icons/64x64/strawberry.png DESTINATION share/icons/hicolor/64x64/apps/)
  install(FILES ../data/icons/128x128/strawberry.png DESTINATION share/icons/hicolor/128x128/apps/)
  install(FILES unix/org.strawberrymusicplayer.strawberry.desktop DESTINATION share/applications)
  install(FILES unix/org.strawberrymusicplayer.strawberry.appdata.xml DESTINATION share/metainfo)
  install(FILES unix/strawberry.1 DESTINATION share/man/man1)
endif()

if(APPLE)
  install(FILES "${CMAKE_CURRENT_BINARY_DIR}/macos/Info.plist" DESTINATION "${CMAKE_BINARY_DIR}/strawberry.app/Contents")
  install(FILES "${CMAKE_CURRENT_SOURCE_DIR}/macos/strawberry.icns" DESTINATION "${CMAKE_BINARY_DIR}/strawberry.app/Contents/Resources")
endif()